Extra tracks: ModifyGameCode (Part 1 of 4)

       Name: ModifyGameCode (Part 1 of 4)                            [Show more]
       Type: Subroutine
   Category: Extra tracks
    Summary: Modify the game code to support the extra track data
    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * CallTrackHook calls ModifyGameCode


 The code modifications are done in four parts.

 The (modifyAddressHi modifyAddressLo) table contains the locations in the main
 game code that we want to modify.

 The (newContentHi newContentLo) table contains the new two-byte addresses that
 we want to poke into the main game code at the modify locations.

 This part also does a couple of single-byte modifications.

 This is also where the xTrackSegmentO table is built, once the modifications
 have been done. The routine is padded out to be exactly 40 bytes long, so
 there's one byte for each inner segment x-coordinate.


.ModifyGameCode

 LDX #19                \ We are about to modify 20 two-byte addresses in the
                        \ main game code, so set a counter in X

.mods1

 LDA modifyAddressHi,X  \ Set (U T) = the X-th entry in the (modifyAddressHi
 STA U                  \ modifyAddressLo) table, which contains the location
 LDA modifyAddressLo,X  \ of the code to modify in the main game code
 STA T

 LDY #0                 \ We now modify two bytes, so set an index in Y

 LDA newContentLo,X     \ We want to modify the two-byte address at location
                        \ (U T), setting it to the new address in the
                        \ (newContentHi newContentLo) table, so set A to the
                        \ low byte of the X-th entry from the table, i.e. to
                        \ the low byte of the new address

 STA (T),Y              \ Modify the byte at (U T) to the low byte of the new
                        \ address in A

 INY                    \ Increment Y to point to the next byte

 LDA newContentHi,X     \ Set A to the high byte of the X-th entry from the
                        \ table, i.e. to the high byte of the new address

 STA (T),Y              \ Modify the byte at (U T) + 1 to the high byte of the
                        \ new address in A

 DEX                    \ Decrement the loop counter to move on to the next
                        \ address to modify

 BPL mods1              \ Loop back until we have modified all 20 addresses

 LDA #&4C               \ ?&261A = &4C (opcode for a JMP &xxxx instruction)
 STA &261A

 STA &248B              \ ?&248B = &4C (opcode for a JMP &xxxx instruction)

 JMP mods2              \ Jump to part 2

 EQUB &00               \ This byte pads the routine out to exactly 40 bytes